cad命令窗口自定義方法教程

1、默認(rèn)設(shè)置：
HKEY_CURRENT_USER\Console


2、自定義設(shè)置：
[HKEY_CURRENT_USER\Console\%SystemRoot%_system32_cmd.exe]


3、鍵及值：
"WindowPosition"=dword:00640104
"CodePage"=dword:000003a8
"FontSize"=dword:00100008
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"HistoryNoDup"=dword:00000000
"FullScreen"=dword:00000000
"ScreenColors"=dword:000000ce
"ScreenBufferSize"=dword:12c0050


4、鍵值意義：
各鍵值均為十六進(jìn)制表示
窗口位置-----WindowPosition---高四位為上，低四位為左。
                              如00640104，即距屏幕上沿64H=100，距屏幕左沿104H=260
字體大小-----FontSize---------高四位為字高，低四位為字寬
                              如00100008，即字體寬×高=08H×10H=8×16
全屏幕-------FullScreen-------0:窗口 1:全屏幕(此時WindowPosition失效)
窗口尺寸-----WindowSize-------高四位為高度，低四位為寬度
                              默認(rèn)00190050，即高19H=25行，寬50H=80列
緩沖區(qū)尺寸---ScreenBufferSize-高四位為高度，低四位為寬度
                              默認(rèn)012c0050，即高12cH=300行，寬50H=80列
字體顏色-----ScreenColors-----低兩位同color設(shè)置中的字體顏色值
字體類型-----FontFamily-------36:新宋體 30:點(diǎn)陣字體
當(dāng)前代碼頁---CodePage---------默認(rèn)3a8H=936:ANSI/OEM-簡體中文GBK
丟棄舊副本---HistoryNoDup-----0:不丟棄 1:丟棄舊副本


5、自定義與默認(rèn)關(guān)系：
系統(tǒng)首先在自定義里面查找相關(guān)設(shè)置，若自定義中沒有，則到默認(rèn)里面查找。
即自定義優(yōu)先級高于默認(rèn)。


6、批處理設(shè)定窗口屬性
set rr="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
reg delete %rr% /f>nul
reg add %rr% /v "WindowPosition" /t REG_DWORD /d 0x00640104 /f>nul
reg add %rr% /v "WindowSize" /t REG_DWORD /d 0x00190050 /f>nul
reg add %rr% /v "ScreenBufferSize" /t REG_DWORD /d 0x00190050 /f>nul
reg add %rr% /v "FullScreen" /t REG_DWORD /d 0x00000001 /f>nul
reg add %rr% /v "FontSize" /t REG_DWORD /d 0x00100008 /f>nul

7、字體大�。�
(1)點(diǎn)陣字體(較小)
3×5-------00050003
5×8-------00080005
6×12------000c0006
6×13------000d0006
8×16------00100008
8×18------00120008
10×20-----0014000a
10×22-----0016000a
12×27-----001b000c
(2)新宋體(較大)
6----00060000---3*7
8----00080000---4*9
10---000a0000---5*11
12---000c0000---6*14
14---000e0000---7*16
16---00100000---8*18
18---00120000---9*21
20---00140000---10*23
24---00180000---12*27
28---001c0000---14*32
36---00240000---18*41
72---00480000---36*82

以上是自定義cmd窗口屬性的基本知識，下面提供一個實(shí)例，是一個小游戲：猜數(shù)字。

@echo off
set rr="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
reg add %rr% /v "WindowPosition" /t REG_DWORD /d 0x0064020b /f>nul
reg add %rr% /v "WindowSize" /t REG_DWORD /d 0x000e0015 /f>nul
reg add %rr% /v "ScreenBufferSize" /t REG_DWORD /d 0x000e0015 /f>nul
if not defined ff (set ff=0&start cmd /c %0&exit)
::mode con cols=21 lines=14
title 猜數(shù)字
setlocal enabledelayedexpansion
cd /d %TEMP%

>tmp.bat echo @echo off
>>tmp.bat echo title 輸入數(shù)字
>>tmp.bat echo for /l %%%%i in (1,1,6) do echo.
>>tmp.bat echo set /p num=輸入數(shù)字：
>>tmp.bat echo echo %%num%%^>tm.tmp
>>tmp.bat echo exit


:main
cls
set times=0
echo   次   數(shù)字  狀況
:again
set n1=%random:~-1%
set n2=
set n3=
set n4=
:value
set n=%random:~-1%
if "%n2%"=="" if %n% NEQ %n1% set n2=%n%
if "%n3%"=="" if %n% NEQ %n1% if %n% NEQ %n2% set n3=%n%
if "%n4%"=="" if %n% NEQ %n1% if %n% NEQ %n2% if %n% NEQ %n3% set n4=%n%
if "%n4%"=="" goto :value
::echo %n1%,%n2%,%n3%,%n4%
:check
if %times% EQU 8 goto :end
set A=0&set B=0&set m=0
reg add %rr% /v "WindowPosition" /t REG_DWORD /d 0x0064015c /f>nul
reg add %rr% /v "WindowSize" /t REG_DWORD /d 0x000e0015 /f>nul
reg add %rr% /v "ScreenBufferSize" /t REG_DWORD /d 0x000e0015 /f>nul
start /wait cmd /k tmp.bat
reg delete %rr% /f>nul
set /p num=<tm.tmp
del tm.tmp&set /a times+=1
if /i "%num%"=="exit" (del tm.tmp&del tmp.bat&exit)
for %%i in (%n1%,%n2%,%n3%,%n4%) do (
(echo %num%|find "%%i")>nul&&(
set /a B+=1
call set k=%%num:~!m!,1%%
if "%%i"=="!k!" set /a A+=1
)&set /a m+=1
)
echo    %times%   %num%  %A%A%B%B
if %A% NEQ 4 goto :check
del tmp.bat
echo  恭喜你，答對了！
pause>nul
exit

:end
echo.
echo     你已試了8次了！
echo      答案是%n1%%n2%%n3%%n4%
echo      再來一次吧！
set /p ff=
if /i "%ff%"=="N" (del tmp.bat&exit)
goto :main