u-boot內(nèi)存控制器初始化分析

u-boot內(nèi)存控制器在第一階段進(jìn)行初始化：cpu_init_crit --> lowlevel_init
架構(gòu)：ARM9u-boot版本：u-boot-1.1.6這里需要區(qū)分的是ldr指令和ldr偽指令。ldr指令是讀取一個(gè)地址中的數(shù)據(jù)，相當(dāng)于指針的解引用。ldr偽指令直接賦值，"="后面的值賦給"="前面的寄存器就對(duì)了。
還有就是匯編中的地址標(biāo)號(hào)，保存的都是絕對(duì)地址（鏈接地址）。

/* 這段程序的作用就是用存在FLASH中的數(shù)據(jù)來配置內(nèi)存控制器 */

_TEXT_BASE: /* 地址標(biāo)號(hào)，相當(dāng)于指針，這個(gè)地址是鏈接地址 */
.word TEXT_BASE /* 在單板目錄的config.mk文件中定義 */

.globl lowlevel_init
lowlevel_init:
ldr r0, =SMRDATA /* 賦值偽指令 r0 = 0x33F8xxxx */
ldr r1, _TEXT_BASE /* 讀內(nèi)存指令 r1 = 0x33F80000 */
sub r0, r0, r1 /* r0 = SMRDATA標(biāo)號(hào)在NOR FLASH中的地址 */
ldr r1, =BWSCON /* r1 = 內(nèi)存控制器寄存器組的開始地址 */
add r2, r0, #13*4 /* r2 = 數(shù)據(jù)池的結(jié)束地址，下面的內(nèi)存池正好13行 */
0:
ldr r3, [r0], #4 /* 讀取數(shù)據(jù)池中的數(shù)據(jù)，r0指向下一個(gè)地址 */
str r3, [r1], #4 /* 用讀取的數(shù)據(jù)存入配置內(nèi)存控制器的寄存器 */
cmp r2, r0 /* 判斷數(shù)據(jù)池是否讀取完畢 */
bne 0b /* 沒有讀取完畢則跳到0標(biāo)號(hào)繼續(xù)讀取 */

mov pc, lr

.ltorg /* 聲明一個(gè)數(shù)據(jù)緩沖池 */

SMRDATA:
.word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
.word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
.word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
.word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
.word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
.word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
.word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
.word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
.word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
.word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
.word 0x32
.word 0x30
.word 0x30